plugins {
    id "net.fabricmc.fabric-loom" version "${loom_version}"
    id 'maven-publish'
}

version = project.mod_version
group = project.maven_group

base {
    archivesName = project.archives_base_name
}

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
    maven {
        name = "FDD Maven"
        url = "https://maven.firstdark.dev/releases"
    }
}

dependencies {
    // mc
    minecraft "com.mojang:minecraft:${project.minecraft_version}"

    // fabric & su api
    implementation "net.fabricmc:fabric-loader:${project.loader_version}"
    implementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"

    // sistema de eventos
    include(implementation  "com.github.retuci0:neutrino:${project.neutrino_version}")

    // rpc de discord
    include(implementation "dev.firstdark.discordrpc:discord-rpc:${project.discord_rpc_version}")
}

loom {
    accessWidenerPath = file("src/main/resources/sputnik.accesswidener")
}

processResources {
    inputs.property "version", project.version
    inputs.property "loader_version", project.loader_version
    inputs.property "minecraft_version", project.minecraft_version
    inputs.property "jdk_version", project.jdk_version

    filesMatching("fabric.mod.json") {
        expand(
                "version": project.version,
                "loader_version": project.loader_version,
                "minecraft_version": project.minecraft_version,
                "jdk_version": project.jdk_version
        )
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = jdk_version.toInteger()
}

java {
    sourceCompatibility = JavaVersion.toVersion(jdk_version)
    targetCompatibility = JavaVersion.toVersion(jdk_version)
}

jar {
    inputs.property "archivesName", project.base.archivesName

    from("LICENSE") {
        rename {
            "${it}_${inputs.properties.archivesName}"
        }
    }
}

publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archives_base_name
            from components.java
        }
    }

    repositories {}
}